Wikidata tailerrean ikasitakoa aplikatzen: Euskal Herriko (eta munduko) emakume informatikariak

2017/07/06 · Asier Iturralde

Astelehenean UEUk Euskal Wikilarien Kultura Elkartea, IXA taldea eta ALDEErekin elkarlanean antolatutako Wikidata tailerrean izan nintzen. Artikulu honetan egunaren kronikatxoa eta bertan ikasitakoa azaltzeko egindako adibide bat aurkituko duzu.

Aurkibidea

Wikidata tailerra

Zer da Wikidata?

Wikidatako datuak nola kontsultatu

Wikidatako datuak Wikipedian nola bistaratu

 

Wikidata tailerra

 

Esan bezala, astelehenean UEUk Euskal Wikilarien Kultura Elkartea, IXA taldea eta ALDEErekin elkarlanean Tabakalera zentroko Hirikilabs gunean antolatutako Wikidata tailerrean izan nintzen. Egun interesgarria izan zen. Goizean Wikipedia, Wikidata eta Wikimedia Commonsi buruzko informazio orokorra jaso ondoren lantegi tematikoekin hasi ginen. Hasiera batean 3 lantegi aurreikusita bazeuden ere (Commons-era edukiak igotzekoa, Wikidatara datuak igotzekoa eta SPARQL erabiliz Wikidatako datuak ustiatzekoa), azkenean laugarren bat ere sortu zen espontaneoki, Wikiemakumeek osatutakoa.

 

Wikidata tailerrean parte hartu genuen wikilariak (Argazkia: UEU)

 

Arratsaldean goizean ikasitakoa praktikan jarri genuen Editatoi eta Hackatoiean. Emaitza interesgarriak eman zituen ekitaldiak, besteak beste hauek dira bertan bildutako wikilariok egin genituenak: Arabako, Bizkaiko, Gipuzkoako, Lapurdiko, Nafarroa Behereko, Nafarroa Garaiko eta Zuberoako mendien taulak wikidatatik elikatzeko prestatu, 2017ko Frantziako Tourreko etapen tauletan eguneko emaitzak automatikoki bistaratzeko txantiloiak egin, Euskal Herriko ia 400 lekuri argazkiak gehitu Wikidatan, Nafarroako 10 haitzuloren informazioa gehitu Wikidatan, Euskal Herriko 300 musika talde baino gehiago musika talde direla adierazi Wikidatan, Wikiemakume proiektuari buruzko orrialdea sortu eta Wikidatako datuekin emakumeei buruzko zerrenda eta grafikoak sortu...

Egunak emandakoaren xehetasun guztiak Wikipediako UEU ikastaroa Wikiproiektuan dago.

Ni batez ere SPARQL erabiliz erabiliz Wikidatako datuak ustiatzen ikasi eta ikasitakoa erabiliz Euskal Herriko herrialde guztietako mendien datuen taulak sortzen aritu nintzen.

Wikilariak lan-taldeetan (Argazkia: Tabakalera)

 

Zer da Wikidata?

Wikidata auzolanean editatutako ezagutza-base eleanitz librea da, Wikimedia Fundazioak sortua. Creative Commons Zero (CC0) lizentzia duenez edozeinek erabil ditzake bertako datuak nahi duenerako. Wikidataren logoak (goian) badu kuriositate bat, logoko barra-kodean WIKI hitza Morse bidez kodetuta agertzen da.

Wikipedian ez bezala Wikidatan ezagutza modu egituratu batean gordetzen da RDF (Resource Description Framework) formatua erabiliz.

 

IXA taldeko Ander Barrenak azaldu zigun bezala RDFren oinarria hirukotea da:

baliabidea => propietatea => balioa

Beste modu batera esanda:

subjektua => predikatua => objektua

 

Adibide batzuekin errazago ulertzen da:

Lasarte-Oria => honen instantzia da => udalerria

Lasarte-Oria => entitate administratibo honetan kokatua dago => Gipuzkoa
Ada Lovelace => honen instantzia da => gizakia

Ada Lovelace => sexu edo generoa => emakumea

Ada Lovelace => lanbidea => matematikaria, programatzailea, poeta, informatikaria, ingeniaria

 

Informazioa modu egituratuan gordetzeak kontsulta ahaltsuak egiteko aukera ematen du. Adibidez, zein dira alkate bezala emakume bat dute munduko hiririk handienak?

 

Wikidatako datuak nola kontsultatu

 

Wikidatako datuak nola erabil ditzakegun ikusteko adibide sinple bat egingo dugu. Lehen Wikiemakumeak proiektua aipatu dudanez eta iametza teknologia berriak erabiltzen dituen komunikazio enpresa bat denez Euskal Herriko emakume informatikarien datuak eskuratuko ditugu Wikidatatik.

Wikidatan kontsultak egiteko SPARQL kontsulta lengoai semantikoa erabiltzen da. Datu-base erlazional batean SQL kontsultak egiten baldin badakizu ezaguna egingo zaizu.

Euskal Herriko emakume informatikarien datuak eskuratzeko kontsulta hau da:

#Euskal Herriko emakume informatikariak
SELECT ?informatikaria ?informatikariaLabel ?jaioterria ?jaioterriaLabel ?jaiotza_data ?heriotza_data ?sexua_edo_generoa ?koord ?irudia WHERE {
  ?informatikaria wdt:P21 wd:Q6581072.
  ?informatikaria wdt:P106 wd:Q82594.
  ?informatikaria wdt:P19 ?jaioterria.
  { ?jaioterria wdt:P131* wd:Q3995. }
  UNION
  { ?jaioterria wdt:P131* wd:Q4018. }
  UNION
  { ?jaioterria wdt:P131* wd:Q671023. }
  UNION
  { ?jaioterria wdt:P131* wd:Q638503. }
  UNION
  { ?jaioterria wdt:P131* wd:Q673040. }
  OPTIONAL { ?jaioterria wdt:P625 ?koord. }
  OPTIONAL { ?informatikaria wdt:P569 ?jaiotza_data. }
  OPTIONAL { ?informatikaria wdt:P570 ?heriotza_data. }
  OPTIONAL { ?informatikaria wdt:P21 ?sexua_edo_generoa. }
  OPTIONAL { ?informatikaria wdt:P18 ?irudia. }
  SERVICE wikibase:label {
     bd:serviceParam wikibase:language "eu" .
  }
}
ORDER BY ASC(?informatikariaLabel)

 

Euskarara itzulita hau litzateke kontsulta, hautatu baldintza hauekin bat datozen datu-baseko elementuak:

  • sexu edo generoa (wdt:P21) emakumea (wd:Q6581072) izatea

  • lanbidea (wdt:P106) informatikaria (wd:Q82594) izatea

  • jaioterriaren (wdt:P19) kasuan UNIONak egiten ditugu lurralde entitate administratibo (wdt:P131) hauetako batekoa izan dadin: Euskal Autonomi Erkidegoa (wd:Q3995), Nafarroako Foru Erkidegoa (wd:Q4018), Lapurdi (wd:Q671023), Nafarroa Beherea (wd:Q638503) edo Zuberoa (wd:Q673040)

 

Hautazko datuak ere eskuratzen ditugu, baldin badaude:

  • Jaioterriaren koordenatuak (wdt:P625)

  • Jaiotza data (wdt:P569)

  • Heriotza data (wdt:P570)

  • Sexua edo generoa (wdt:P21)

  • Informatikariaren irudia (wdt:P18)

 

SERVICE wikibase:label {bd:serviceParam wikibase:language "eu"} informatikariaren eta bere jaioterriaren testuak euskaraz nahi ditugula adierazteko erabiltzen da.

 

Amaierako ORDER BYak emaitzak informatikariaren izenaren arabera ordenatzeko adierazten du.

 

OHARRA: (2017-07-10) Euskarazko Wikipediaren Twitter-eko kontutik Euskal Herrian jaioa den egiaztatzeko modu sinpleago baten berri eman didate:

 

 

Hobekuntza hori kontutan izanda honela geratzen da kontsulta:

 

#Euskal Herriko emakume informatikariak
SELECT ?informatikaria ?informatikariaLabel ?jaioterria ?jaioterriaLabel ?jaiotza_data ?heriotza_data ?sexua_edo_generoa ?koord ?irudia WHERE {
  ?informatikaria wdt:P21 wd:Q6581072.
  ?informatikaria wdt:P106 wd:Q82594.
  ?informatikaria wdt:P19 ?jaioterria.
  ?informatikaria wdt:P19/wdt:P131*/^wdt:P527 wd:Q47588
  OPTIONAL { ?jaioterria wdt:P625 ?koord. }
  OPTIONAL { ?informatikaria wdt:P569 ?jaiotza_data. }
  OPTIONAL { ?informatikaria wdt:P570 ?heriotza_data. }
  OPTIONAL { ?informatikaria wdt:P21 ?sexua_edo_generoa. }
  OPTIONAL { ?informatikaria wdt:P18 ?irudia. }
  SERVICE wikibase:label {
     bd:serviceParam wikibase:language "eu" .
  }
}
ORDER BY ASC(?informatikariaLabel)

 

 

Horrelako kontsultak egiteko Wikidatak orri berezi bat dauka: https://query.wikidata.org/

 

Bertan kontsulta itsatsi eta Run botoia sakatzen baduzu egindako kontsultarekin bat datozen emakume informatikarien datuak agertuko zaizkizu: izen-abizenak, jaioterria, jaioterriaren koordenatuak eta irudia.

 

Hemen ikus dezakezu kontsultaren emaitza:

 

 

Kasu honetan bezala emaitzan koordenatuak daudenean mapa batean bistaratzeko aukera ematen du Wikidatak. Mapako puntuetan klikatzen baduzu dagokion emakume informatikariaren datuak eta argazkia agertuko zaizu:

 

 

Wikidatako datuak Wikipedian nola bistaratu

 

Wikipedian Wikidatako datuak erabiltzeak abantaila nabarmenak dauzka:

  • Wikidatan datuak behin sartzearekin nahikoa da

  • Hizkuntza guztietako Wikipedietan erabil daitezke

  • Automatikoki eguneratzen dira datuak, ez dago banan bana datu hori erabilitako leku guztietan eskuz aldatu beharrik, Wikidatan aldatzearekin nahikoa.

 

Adibidez, udalerrien datu demografikoak, alkatea eta abar maiz eguneratu behar izaten dira. Orain arte eskuz egin beharreko lan neketsua zen. Udalerri baten Wikipediako orria 25 hizkuntzatan badago 25 aldiz aldatu behar ziren datu horiek. Orri horiek Wikidatatik datuak hartzeko egokituz gero berriz, nahikoa litzateke datu horiek Wikidatan behin aldatzearekin, Wikipediako orrietako informazioa automatikoki eguneratuko bailitzateke. Hau hizkuntza txikietako Wikipedientzat da bereziki mesedegarria.

 

 

Gure adibidearekin jarraituz, Wikidatatik eskuratutako datuen zerrendak bistaratzeko txantiloi hau erabiltzen da:

https://eu.wikipedia.org/wiki/Txantiloi:Wikidata_list

 

Bertan prestatu dugun SPARQL kontsulta jarri behar da eta zerrendaren bistaratze aukerak zehaztu. Emaitza hemen ikus dezakezu:

https://eu.wikipedia.org/wiki/Wikiproiektu:WikiEmakume/Wikidatan_dauden_Euskal_Herriko_emakume_informatikarien_zerrenda

 

Wikidatako datuak erabiliz Wikipedian sortutako taularen zati baten pantaila-argazkia

 

Mundu osoko emakume informatikarien zerrenda ere sortu dut:

https://eu.wikipedia.org/wiki/Wikiproiektu:WikiEmakume/Wikidatan_dauden_emakume_informatikarien_zerrenda

 

Mapan ikusten denez oraindik ez dago Nafarroako eta Ipar Euskal Herriko emakume informatikaririk Wikidatan. Wikipedia eta Wikidata guztion artean egiten ditugu, animatu eta gehitu emakume informatikari gehiago! Gehitu ahala taula horiek automagikoki eguneratuko dira :)

 

Creative Commons Lizentzia

Artikulu honek Creative Commons Aitortu-PartekatuBerdin 4.0 Nazioartekoa (CC BY-SA 4.0) lizentzia dauka. Kopiatu, moldatu, zabaldu eta argitaratzeko libre zara, beti ere, nire egiletza aitortzen baduzu eta baldintza beretan egiten baduzu.


facebook
0
twitter
iametza interaktiboa

Zirkuitu ibilbidea 2 - 1. pabiloia
Lasarte-Oria (Gipuzkoa)

T (+34) 943 376 716
F (+34) 943 372 772

kaixo@iametza.eus

Euskarabildua Puntu eus
iametza interaktiboa iametza interaktiboa iametza interaktiboa iametza interaktiboa iametza interaktiboa iametza interaktiboa
©2015 iametza interaktiboa